Access VBA教程:ItemRemoved事件

该主题中的某些内容可能不适用于某些语言。

当从项目中删除引用时,ItemRemoved事件发生。

说明

只有在从代码中删除引用时,该事件才会发生。执行以下操作时该事件不会发生:当“模块”窗口为活动窗口时,单击“工具”菜单中的“引用”显示“引用”对话框,在“引用”对话框中删除引用。

VBA示例

以下示例包含 ItemAdded 与 ItemRemoved事件的事件过程。若要试用该示例,请新建一个类模块,方法是:单击“插入”菜单中的“类模块”,然后将下列代码粘贴到类模块中,并将类模块保存为 RefEvents:


' Declare object variable to represent References collection.
Public WithEvents evtReferences As References
' When instance of class is created, initialize evtReferences
' variable.
Private Sub Class_Initialize()
    Set evtReferences = Application.References
End Sub
' When instance is removed, set evtReferences to Nothing.
Private Sub Class_Terminate()
    Set evtReferences = Nothing
End Sub
' Display message when reference is added.
Private Sub evtReferences_ItemAdded(ByVal Reference As _
        Access.Reference)
    MsgBox "Reference to " & Reference.Name & " added."
End Sub
' Display message when reference is removed.
Private Sub evtReferences_ItemRemoved(ByVal Reference As _
        Access.Reference)
    MsgBox "Reference to " & Reference.Name & " removed."
End Sub

下一个 Function 过程删除指定的引用。当删除引用时,将执行 RefEvents 类中定义的 ItemRemoved事件过程。

例如,若要删除对日历控件的引用,可以传递“MSACAL”字符串。该字符串是代表日历控件的 Reference对象的名称。


Function RemoveReference(strRefName As String) As Boolean
    Dim ref As Reference
    On Error GoTo Error_RemoveReference
    ' Return object representing existing reference.
    Set ref = objRefEvents.evtReferences(strRefName)
    ' Remove reference from collection.
    objRefEvents.evtReferences.Remove ref
    RemoveReference = True
Exit_RemoveReference:
    Exit Function
Error_RemoveReference:
    MsgBox Err & ": " & Err.Description
    RemoveReference = False
    Resume Exit_RemoveReference
End Function

上页:Access VBA教程:ItemAdded事件 下页:Access VBA教程:KeyDown事件

Access VBA教程:ItemRemoved事件

Access VBA教程:KeyDown事件 Access VBA教程:KeyPress事件
Access VBA教程:KeyUp事件 Access VBA教程:Load事件
Access VBA教程:LostFocus事件 Access VBA教程:MouseDown事件
Access VBA教程:作为位掩码的固有常量 Access VBA教程:MouseMove事件
Access VBA教程:MouseUp事件 Access VBA教程:MouseWheel事件
Access VBA教程:NoData事件 Access VBA教程:NotInList事件
Access VBA教程:OnConnect事件 Access VBA教程:OnDisconnect事件
Access VBA教程:Open事件 Access VBA教程:Page事件
Access VBA教程:PivotTableChange事件 Access VBA教程:Print事件
Access VBA教程:Progress事件 (Snapshot Viewer) Access VBA教程:Query事件
版权所有 © 中山市飞娥软件工作室 证书:粤ICP备09170368号