Access VBA教程:DeleteLines方法

DeleteLines方法从标准模块或类模块中删除代码行。

expression.DeleteLines(StartLine, Count)

expression   必需。返回“Applies To”列表中的一个对象的表达式。

StartLine  必需 Long 型。Long 型值,指定要删除的起始行的行号。

Count  必需 Long 型。Long 型值,指定要删除的行数。

说明

模块中行的编号从 1 开始。若要确定模块中的行数,请使用CountOfLines属性。

若要以一行替换另一行,请使用ReplaceLine方法。

VBA示例

下面的示例从模块中删除指定的行:


Function DeleteWholeLine(strModuleName, strText As String) _
     As Boolean
    Dim mdl As Module, lngNumLines As Long
    Dim lngSLine As Long, lngSCol As Long
    Dim lngELine As Long, lngECol As Long
    Dim strTemp As String
    On Error GoTo Error_DeleteWholeLine
    DoCmd.OpenModule strModuleName
    Set mdl = Modules(strModuleName)
    If mdl.Find(strText, lngSLine, lngSCol, lngELine, lngECol) Then
        lngNumLines = Abs(lngELine - lngSLine) + 1
        strTemp = LTrim$(mdl.Lines(lngSLine, lngNumLines))
        strTemp = RTrim$(strTemp)
        If strTemp = strText Then
            mdl.DeleteLines lngSLine, lngNumLines
        Else
            MsgBox "Line contains text in addition to '" _
                & strText & "'."
        End If
    Else
        MsgBox "Text '" & strText & "' not found."
    End If
    DeleteWholeLine = True
Exit_DeleteWholeLine:
    Exit Function
Error_DeleteWholeLine:
    MsgBox Err & " :" & Err.Description
    DeleteWholeLine = False
    Resume Exit_DeleteWholeLine
End Function

可以从以下过程中调用该函数,从而在模块“模块1”中搜索常量的声明语句并将其删除。


Sub DeletePiConst()
    If DeleteWholeLine("Module1", "Const conPi = 3.14") Then
        Debug.Print "Constant declaration deleted successfully."
    Else
        Debug.Print "Constant declaration not deleted."
    End If
End Sub

上页:Access VBA教程:DeleteControl方法 下页:Access VBA教程:DeleteReportControl方法

Access VBA教程:DeleteLines方法

Access VBA教程:DeleteReportControl方法 Access VBA教程:DFirst方法
Access VBA教程:DiscardConflict方法 Access VBA教程:DLast方法
Access VBA教程:DLookup方法 Access VBA教程:DMax方法
Access VBA教程:DMin方法 Access VBA教程:Dropdown方法
Access VBA教程:DStDev方法 Access VBA教程:DStDevP方法
Access VBA教程:DSum方法 Access VBA教程:DVar方法
Access VBA教程:DVarP方法 Access VBA教程:Echo方法
Access VBA教程:Eval方法 Access VBA教程:ExportXML方法
Access VBA教程:Find方法 Access VBA教程:FirstPage、LastPage、NextPage、PreviousPage方法 (Snapshot Viewer)
Access VBA教程:Follow方法 Access VBA教程:FollowHyperlink方法
版权所有 © 中山市飞娥软件工作室 证书:粤ICP备09170368号