FrontPage VBA教程:MaximumValue属性

返回或设置 Variant 类型的值,该值指定此域允许的最大值。此属性相当于在用户界面的“修改域”对话框中设置“允许的最大值”域。可读写。

expression.MaximumValue

expression  必选。返回“应用于”列表中的对象之一的表达式。

说明

如果此域输入非法数据,则将向用户显示错误信息。使用MinimumValue属性值设置此域的最小值。

VBA示例

以下示例显示 fpFieldNumber 和 fpFieldCurrency 类型的所有域的名称和最大值。如果列表不包含此种类型的域,则向用户显示一条消息。


Sub DisplayMaximum()
'Displays the maximum value of all ListFieldNumber
'and ListFieldCurrency fields in the list
    Dim objApp As FrontPage.Application
    Dim objLstFlds As ListFields
    Dim strName As String
    Dim objLstFld As Object
    Dim strValues As String
    Set objApp = FrontPage.Application
    Set objLstFlds = objApp.ActiveWeb.Lists.Item(0).Fields
    'Cycle through lists and add value to string
    For Each objLstFld In objLstFlds
        If (objLstFld.Type = fpFieldNumber) Or (objLstFld.Type = fpFieldCurrency) Then
            strValues = strValues & objLstFld.Name & vbTab & _
                        objLstFld.MaximumValue & vbCr
        End If
    Next objLstFld
    If strValues <> "" Then
        MsgBox "The fields and their maximum values are:" & vbCr & _
                vbCr & strValues
    Else
        MsgBox "There are no ListFieldNumber or ListFieldCurrency Fields in the current list."
    End If
End Sub

以下示例将 ListFieldNumber 类型的所有域的最大值更改为常数 200。

注意 使用ApplyChanges方法来应用对列表所做的更改。


Sub ChangeMaximum()
'Changes maximum value for all fields of type
'ListFieldNumber
    Dim objApp As FrontPage.Application
    Dim objLstFlds As ListFields
    Dim strName As String
    Dim objLstFld As Object
    Const varMax As Variant = 200
    Set objApp = FrontPage.Application
    If objApp.ActiveWeb.Lists.Count > 0 Then
        Set objLstFlds = objApp.ActiveWeb.Lists.Item(0).Fields
        'Cycle through lists and change values
        For Each objLstFld In objLstFlds
            If objLstFld.Type = fpFieldNumber Then
                objLstFld.MaximumValue = varMax
            End If
        Next objLstFld
        objApp.ActiveWeb.Lists(0).ApplyChanges
    Else
        MsgBox "The active web contains no lists."
    End If
End Sub

上页:FrontPage VBA教程:LookupField属性 下页:FrontPage VBA教程:MaxLength属性

FrontPage VBA教程:MaximumValue属性

FrontPage VBA教程:MaxLength属性 FrontPage VBA教程:MetaTag属性
FrontPage VBA教程:mimeType 类型 FrontPage VBA教程:MinimumValue属性
FrontPage VBA教程:MonthsShown属性 FrontPage VBA教程:mseMode属性
FrontPage VBA教程:Name属性 FrontPage VBA教程:nameProp属性
FrontPage VBA教程:NavigationNode属性 FrontPage VBA教程:NewForm属性
FrontPage VBA教程:NewPageorWeb属性 FrontPage VBA教程:Next属性
FrontPage VBA教程:NumberOfLines属性 FrontPage VBA教程:OlderFile属性
FrontPage VBA教程:onafterupdate属性 FrontPage VBA教程:onbeforeupdate属性
FrontPage VBA教程:onclick属性 FrontPage VBA教程:ondblclick属性
FrontPage VBA教程:ondragstart属性 FrontPage VBA教程:onhelp属性
版权所有 © 中山市飞娥软件工作室 证书:粤ICP备09170368号