Outlook VBA教程:Add方法

应用于 Actions对象的 Add方法。

Actions集合中创建新动作,并将该新动作作为Action对象返回。

expression.Add

expression  必选。该表达式返回 Actions集合对象。

应用于 AddressEntries对象的 Add方法。

AddressEntries集合添加新条目,并将该新条目作为 AddressEntry对象返回。

expression.Add(Type, Name, Address)

expression  必选。该表达式返回 AddressEntries对象。

Type  必选,String 类型。新条目的类型。

Name  可选,Variant 类型。新条目的名称。

Address  可选,Variant 类型。地址。

应用于 Attachments对象的 Add方法。

AddressEntries集合中创建新地址条目,并且将新地址作为AddressEntry对象返回。

注意 只有在调用了Update方法后,新条目或对现有条目的更改才能在集合中持续。

expression.Add(Source, Type, Name, Address)

expression   必选。该表达式返回 AddressEntries集合对象。

Source       必选,String 类型。附件的源。

Type        必选,String 类型。地址条目的类型。

Name     可选,String 类型。地址条目的显示名称。

Address   可选,String 类型。地址条目的电子邮件地址。

应用于 Explorers对象的 Add方法。

创建浏览器窗口的新实例,并将窗口的新实例作为 Explorer对象返回。

expression.Add(Folder, DisplayMode)

expression  必选。该表达式返回Explorers集合。

Folder   必选。创建浏览器窗口时,在该窗口中显示的 Variant对象。

DisplayMode  可选,Long 类型。文件夹的显示模式。可为下列OlFolderDisplayMode 常量之一:

OlFolderDisplayMode 可以是以下 OlFolderDisplayMode 常量之一。
olFolderDisplayFolderOnly
olFolderDisplayNoNavigation
olFolderDisplayNormal

注意  参数 Folder 可以代表 MAPIFolder对象或文件夹的 URL。

应用于 Folders对象的 Add方法。

Folders集合中创建新文件夹,并将该新文件夹作为MAPIFolder对象返回。

expression.Add(Name, Type)

expression  必选。该表达式返回 Folders对象。

Name   String 类型,必选。新文件夹的显示名称。

Type  可选,Long 类型。新文件夹的 Outlook 文件夹类型。如果没有指定文件夹类型,则默认新文件夹与创建它的文件夹类型相同。可为以下 OlDefaultFolders 常量之一: olFolderCalendar、olFolderContacts、olFolderDrafts、olFolderInbox、olFolderJournal、olFolderNotes 或 olFolderTasks。(本参数不能指定为 olFolderDeletedItems、olFolderOutbox 和 olFolderSentMail 常量。)

应用于 Inspectors对象的 Add方法。

创建新的检查器窗口并返回所创建的Inspector对象。

expression.Add(Item)

expression  必选。该表达式返回Inspectors集合对象。

Item   必选,Object 类型。创建检查器窗口时显示在其中的项目。

应用于 ItemProperties对象的 Add方法。

将 ItemProperty对象添加到 ItemProperties集合。

expression.Add(Name, Type, AddToFolderFields, DisplayFormat)

expression  必选。该表达式返回ItemProperties对象。

Name  必选,String 类型。新项目属性对象的名称。

Type  必选,OlUserPropertyType 常量。新的 ItemProperty对象的类型。

OlUserPropertyType 可为以下 OlUserPropertyType 常量之一。
olCombination
olCurrency
olDateTime
olDuration
olFormula
olKeywords
olNumber
olOutlookInternal
olPercent
olText
olYesNo

AddToFolderFields  可选,Variant 类型。决定 ItemProperty 是否在文件夹中显示为字段。如果值为 True,该字段将显示在文件夹中。

DisplayFormat  可选,Variant 类型。定义该字段显示在给定文件夹中时的格式。

应用于 Items对象的 Add方法。

在文件夹的Items集合中创建新的 Outlook 项目,并返回该新项目。如果未指定项目的类型,项目的Type 将默认为文件夹的类型,或者,如果父文件夹没有类型时默认为MailItem

expression.Add(Type)

expression  必选。该表达式返回 Items集合对象。

Type  可选,Variant 类型。新项目的 Outlook 项目类型。可以是下列 OlItemType 常量之一:olAppointmentItem、olContactItem、olJournalItem、olMailItem、olNoteItem、olPostItem 或 olTaskItem。或者是下列 OlOfficeDocItemsType 常量之一:olExcelWorkSheetItem、olPowerPointShowItem 或 olWordDocumentItem。或者是任何有效的邮件类。指定用于创建自定义窗体的MessageClass

应用于 Links对象的 Add方法。

通过在与项目关联的Links集合中添加Link对象,将其他项目链接到该项目。

expression.Add(Item)

expression  必选。该表达式返回 Links集合对象。

Item  必选,Object 类型。要链接到与 Links集合关联的项目中的项目。

应用于 OutlookBarGroups对象的 Add方法。

在 Outlook 面板中添加新的空组,并将新组作为OutlookBarGroup对象返回。

expression.Add(Name, Index)

expression  必选。该表达式返回OutlookBarGroups集合。

Name  必选,String 类型。所创建的组的名称。

Index  可选,Long 类型。新组将插入到 Outlook 面板中的位置。位置 1 位于面板的顶部。

应用于 OutlookBarShortcuts对象的 Add方法。

向 Outlook 面板上的组中添加新的快捷方式,并且将该新快捷方式作为OutlookBarShortcut对象返回。

expression.Add(Target, Name, Index)

expression  必选。该表达式返回OutlookBarShortcuts集合对象。

Target  必选,Variant 类型。要创建的快捷方式的目标。

Name  必选,String 类型。要创建的快捷方式的名称。

Index  可选,Long 类型。新快捷方式插入到 Outlook 面板组中的位置。位置 1 代表组的顶部。

Target 类型取决于快捷方式的类型。如果类型为 MAPIFolder,快捷方式代表 Microsoft Outlook 文件夹。如果类型为 String,则快捷方式代表文件系统的路径或 URL。

应用于 Pages对象的 Add方法。

Pages集合中创建新的页面,并返回该新对象。Pages集合初始为空,每个集合至多能有 5 个可自定义的页面。

expression.Add(Name)

expression  必选。该表达式返回 Pages集合对象。

Name  必选,String类型。页面的名称。

应用于 PropertyPages对象的 Add方法。

将新的自定义属性页添加到 Microsoft Outlook 的“选项”对话框或文件夹“属性”对话框中。

expression.Add(Page, Title)

expression  必选。该表达式返回PropertyPages集合对象。

Page  必选,Variant 类型。要添加到对话框中的属性页。

Title  可选,String 类型。要显示在属性页选项卡上的标题。

应用于 Recipients对象的 Add方法。

Recipients集合中创建新的收件人,并将该新收件人作为Recipient对象返回。

expression.Add(Name)

expression  必选。该表达式返回 Recipients集合对象。

Name  必选,String 类型。收件人的显示名称。

应用于 UserProperties对象的 Add方法。

UserProperties集合中创建新的用户属性,并将新属性作为UserProperty对象返回。

expression.Add(Name, Type, AddToFolderFields, DisplayFormat)

expression   必选。该表达式返回 UserProperties集合对象。

Name  必选,String 类型。属性的名称。

Type  必选,OlUserPropertyType 类型。新属性的类型。

OlUserPropertyType 可为以下 OlUserPropertyType 常量之一。
olCombination
olCurrency
olDateTime
olDuration
olFormula
olKeywords
olNumber
olOutlookInternal
olPercent
olText
olYesNo

AddToFolderFields  可选,Boolean 类型。如果属性要添加到文件夹字段中,则为 True,否则为 False。默认值是 True。

DisplayFormat  可选,Long 类型。指定 OlUserPropertyType 常量的索引格式。

应用于 Views对象的 Add方法。

创建新视图。OlViewType。

expression.Add(Name, ViewType, SaveOption)

expression  必选。该表达式返回 Views对象。

Name  必选,String 类型。新视图的名称。

ViewType  必选,OlViewType 类型。新视图的类型。

OlViewType 可为以下 OlViewType 常量之一。
olCalendarView
olCardView
olIconView
olTableView
olTimelineView

SaveOption  可选,olViewSaveOption 常量。指定新视图权限的保存选项。

注意 保存选项的值如下:

VBA示例

用于 Explorers对象时。

说明

该浏览器窗口最初是隐藏的。必须调用 Explorer对象的Display方法显示该窗口。

以下 Microsoft Visual Basic/Visual Basic for Applications 示例在不包含“Outlook 面板”或“文件夹列表”的浏览器窗口中显示“草稿”文件夹。


Dim myOlApp As New Outlook.Application
Dim myExplorers As Outlook.Explorers
Dim myOlExpl As Outlook.Explorer
Dim myFolder As Outlook.MAPIFolder
Set myExplorers = myOlApp.Explorers
Set myFolder = myOlApp.GetNamespace("MAPI").GetDefaultFolder _
    (olFolderDrafts)
Set myOlExpl = myExplorers.Add _
    (myFolder, olFolderDisplayNoNavigation)
myOlExpl.Display

如果使用 VBScript,您不必创建Application对象,而且也不能使用命名常量。本示例说明如何使用 VBScript 执行相同任务。


Set myExplorers = Application.Explorers
Set myFolder = Application.GetNamespace("MAPI").GetDefaultFolder(16)
Set myOlExpl = myExplorers.Add(myFolder, 2)
myOlExpl.Display

用于 Inspectors对象时。

说明

该方法在本质上与GetInspector属性相同。

本 Microsoft Visual Basic/Visual Basic for Applications 示例提示用户输入单位名称,然后使用Restrict方法根据该名称在“联系人”文件夹中查找所有联系人项目,并显示每个项目。


Dim myOlApp As New Outlook.Application
Answer = InputBox("Enter the company name")
Set myFolder = myOlApp.GetNamespace("MAPI") _
    .GetDefaultFolder(olFolderContacts)
Set myItems = myFolder.Items.Restrict("[MessageClass] = 'IPM.Contact'")
Set myRestrictItems = myItems.Restrict("[CompanyName] = " & Answer)
For x = 1 To myRestrictItems.Count
    Set myInspector = myOlApp.Inspectors.Add(myRestrictItems.Item(x))
    myInspector.Display
Next x

如果使用 VBScript,您不必创建Application对象,而且也不能使用命名常量。本示例说明如何使用 VBScript 执行相同任务。


Answer = InputBox("Enter the company name")
Set myFolder = _
    Application.GetNamespace("MAPI").GetDefaultFolder(10)
Set myItems = myFolder.Items.Restrict("[MessageClass] = 'IPM.Contact'")
Set myRestrictItems = myItems.Restrict("[CompanyName] = " & Answer)
For x = 1 To myRestrictItems.Count
    Set myInspector = Application.Inspectors.Add(myRestrictItems.Item(x))
    myInspector.Display
Next

用于 Actions对象时。

本 Visual Basic for Applications 示例创建新的邮件,并使用 Add方法向该邮件中添加Action


Set myOlApp = CreateObject("Outlook.Application")
Set myItem = myOlApp.CreateItem(olMailItem)
Set myAction = myItem.Actions.Add

如果使用 VBScript,您不必创建Application对象,而且也不能使用命名常量。本示例说明如何使用 VBScript 执行相同任务。


Set myItem = Application.CreateItem(0)
Set myAction = myItem.Actions.Add

用于 AddressEntries对象时。

本 VBScript 示例使用CommandButton 的 Click事件。窗体的“收件人”字段中的姓名以及该收件人的经理的姓名都位于“全球通讯簿”中。使用 Add方法将这些条目添加到发件人的“个人通讯簿”中。


Sub CommandButton1_Click()
    myName = Item.To
    Set myNameSpace = Application.GetNameSpace("MAPI")
    Set myGAddressList = myNameSpace.AddressLists("Global Address List")
    Set myGEntries = myGAddressList.AddressEntries
    Set myGEntry = myGEntries(myName)
    myManager = myGEntry.Manager
    Set myGEntry2 = myGEntries(myManager)
    Set myPAddressList = myNameSpace.AddressLists("Personal Address Book")
    Set myPEntries = myPAddressList.AddressEntries
    'Add a new AddressEntry object to the personal
    'address collection with the name, address, and
    'manager of the name in your To field.
    Set myPEntry = myPEntries.Add("Microsoft Mail Address", myName)
    myPEntry.Address = myGEntry.Address
    myPEntry.Manager = myGentry.Manager
    'Update to persist the collection.
    myPEntry.Update
    'Now add the manager's info. to
    'the Personal address collection.
    Set myPEntry2 = myPEntries.Add("Microsoft Mail Address", myManager)
    myPEntry2.Address = myGEntry2.Address
    myPEntry2.Manager = myGentry2.Manager
    myPEntry2.Update
End Sub

用于 Links集合时。

本 Microsoft Visual Basic/Visual Basic for Applications 示例新建任务项目,然后提示用户输入链接到该项目的联系人的姓名。如果找到了该联系人,就将其添加到项目的Links集合中。


Dim myOlApp As New Outlook.Application
Dim myNameSpace As Outlook.NameSpace
Dim myFolder As Outlook.MAPIFolder
Dim myTask As Outlook.TaskItem
Dim myContact As Outlook.ContactItem
Set myTask = myOlApp.CreateItem(olTaskItem)
Set myNameSpace = myOlApp.GetNamespace("MAPI")
Set myFolder = myNameSpace.GetDefaultFolder(olFolderContacts)
tempstr = InputBox("Enter the name of the contact to link to this task")
If tempstr <> "" Then
    tempstr = "[Full Name] = """ & tempstr & """"
    Set myItems = myFolder.Items.Restrict("[MessageClass] = 'IPM.Contact'")
    Set myContact = myItems.Find(tempstr)
    myTask.Links.Add myContact
myTask.Display

如果使用 VBScript,您不必创建Application对象,而且也不能使用命名常量。本示例说明如何使用 VBScript 执行相同任务。


Set myTask = Application.CreateItem(3)
Set myNameSpace = Application.GetNamespace("MAPI")
Set myFolder = myNameSpace.GetDefaultFolder(10)
tempstr = InputBox("Enter the name of the contact to link to this task")
If tempstr <> "" Then
    tempstr = "[Full Name] = """ & tempstr & """"
    Set myItems = myFolder.Items.Restrict("[MessageClass] = 'IPM.Contact'")
    Set myContact = myItems.Find(tempstr)
    myTask.Links.Add myContact
myTask.Display

用于 Folders集合时。

本 Visual Basic for Applications 示例使用 Add方法将名为“My Contacts”的新文件夹添加到当前(默认的)“联系人”文件夹中。


Set myOlApp = CreateObject("Outlook.Application")
Set myNameSpace = myOlApp.GetNameSpace("MAPI")
Set myFolder = myNamespace.GetDefaultFolder(olFolderContacts)
Set myNewFolder = myFolder.Folders.Add("My Contacts")

如果使用 VBScript,您不必创建Application对象,而且也不能使用命名常量。本示例说明如何使用 VBScript 执行相同任务。


Set myNameSpace = Application.GetNameSpace("MAPI")
Set myFolder = myNamespace.GetDefaultFolder(10)
Set myNewFolder = myFolder.Folders.Add("My Contacts")

本 Visual Basic for Applications 示例使用 Add方法在“任务”文件夹中添加两个新文件夹。第一个文件夹“Notes Folder”中将包含便笺项目,第二个文件夹“Contacts Folder”中将包含联系人项目。如果这两个文件夹已经存在,将弹出消息框通知用户。


Set myOlApp = CreateObject("Outlook.Application")
Set myNameSpace = myOlApp.GetNameSpace("MAPI")
Set myFolder = myNamespace.GetDefaultFolder(olFolderTasks)
On Error GoTo ErrorHandler
Set myNotesFolder = myFolder.Folders.Add ("Notes Folder", olFolderNotes)
On Error GoTo ErrorHandler
Set myContactFolder = myFolder.Folders.Add ("Contacts Folder", olFolderContacts)
Exit Sub
ErrorHandler:
 MsgBox "This folder already exists!"

用于 Items集合时。

本 Visual Basic for Applications 示例获取当前“联系人”文件夹,并在其中添加新的ContactItem对象。


Set myOlApp = CreateObject("Outlook.Application")
Set myNameSpace = myOlApp.GetNameSpace("MAPI")
Set myFolder = _
    myNamespace.GetDefaultFolder(olFolderContacts)
Set myItem = myFolder.Items.Add

本 Visual Basic for Applications 示例将自定义窗体添加到默认的“任务”文件夹中。


Set myOlApp = CreateObject("Outlook.Application")
Set myNameSpace = myOlApp.GetNameSpace("MAPI")
Set myFolder = _
    myNamespace.GetDefaultFolder(olFolderTasks)
Set myItems = myFolder.Items
Set myItem = myItems.Add("IPM.Task.myTask")

用于 OutlookBarGroups集合时。

本 Microsoft Visual Basic/Visual Basic for Applications 示例将名为“Marketing”的组作为“Outlook 面板”上的第二个组添加。


Dim myOlApp As New Outlook.Application
Dim myolBar As Outlook.OutlookBarPane
Set myolBar = myOlApp.ActiveExplorer.Panes.Item("OutlookBar")
myolBar.Contents.Groups.Add "Marketing", 2

如果使用 VBScript,则不必创建Application对象。本示例说明如何使用 VBScript 执行相同任务。


Set myolBar = Application.ActiveExplorer.Panes.Item("OutlookBar")
myolBar.Contents.Groups.Add "Marketing", 2

用于 OutlookBarShortcuts集合时。

本 Microsoft Visual Basic/Visual Basic for Applications 示例添加 Web 上的 Microsoft 主页的快捷方式。


Dim myOlApp As New Outlook.Application
Dim myOlBar As Outlook.OutlookBarPane
Dim myolGroup As Outlook.OutlookBarGroup
Dim myOlShortcuts As Outlook.OutlookBarShortcuts
Set myOlBar = myOlApp.ActiveExplorer.Panes.Item("OutlookBar")
Set myolGroup = myOlBar.Contents.Groups.Item(1)
Set myOlShortcuts = myolGroup.Shortcuts
myOlShortcuts.Add "http://www.microsoft.com", _
    "Microsoft Home Page", 3

如果使用 VBScript,则不必创建Application对象。本示例说明如何使用 VBScript 执行相同任务。


Set myOlBar = _
    Application.ActiveExplorer.Panes.Item("OutlookBar")
Set myolGroup = myOlBar.Contents.Groups.Item(1)
Set myOlShortcuts = myolGroup.Shortcuts
myOlShortcuts.Add "http://www.microsoft.com", _
    "Microsoft Home Page", 3

用于 Recipients集合时。

本 Visual Basic for Applications 示例创建新的邮件,使用 Add方法将“Allison Klein”添加为“收件人”,并显示该邮件。


Set myOlApp = CreateObject("Outlook.Application")
Set myItem = myOlApp.CreateItem(olMailItem)
Set myRecipient = myItem.Recipients.Add("Allison Klein")
myItem.Display

如果使用 VBScript,您不必创建Application对象,而且也不能使用命名常量。本示例说明如何使用 VBScript 执行相同任务。


Set myItem = Application.CreateItem(0)
Set myRecipient = myItem.Recipients.Add("Allison Klein")
myItem.Display

用于 UserProperties集合时。

本 Visual Basic for Applications 示例创建一个新的ContactItem对象,并将“LastDateSpokenWith”作为用户属性添加。


Set myOlApp = CreateObject("Outlook.Application")
Set myItem = myOlApp.CreateItem(olContactItem)
Set myUserProperty = myItem.UserProperties _
    .Add("LastDateSpokenWith", olDateTime)

本 Visual Basic for Applications 示例创建新的 ContactItem对象,并将“Notes”作为用户属性添加。通过访问新属性的索引来设置Value


Set myOlApp = CreateObject("Outlook.Application")
Set myItem = myOlApp.CreateItem(olContactItem)
Set myUserProperty = myItem.UserProperties _
    .Add("Notes", olText)
myItem.UserProperties(1).Value = "Neighbor"
 

用于 Views对象时。

以下示例创建名为“New Table”的新视图,并将该视图存储在名为“objNewView”的变量中。


Sub CreateView()
'Creates a new view
    Dim olApp As Outlook.Application
    Dim objName As NameSpace
    Dim objViews As Views
    Dim objNewView As View
    Set olApp = Outlook.Application
    Set objName = olApp.GetNamespace("MAPI")
    Set objViews = objName.GetDefaultFolder(olFolderInbox).Views
    Set objNewView = objViews.Add(Name:="New Table", _
                     ViewType:=olTableView, SaveOption:=olViewSaveOptionThisFolderEveryone)
End Sub

上页:Outlook VBA教程:ActiveWindow方法 下页:Outlook VBA教程:AddMember方法

Outlook VBA教程:Add方法:相关链接

Outlook VBA教程:AddMember方法 Outlook VBA教程:AddMembers方法
Outlook VBA教程:AddStore方法 Outlook VBA教程:AddToFavorites方法
Outlook VBA教程:AddToPFFavorites方法 Outlook VBA教程:AdvancedSearch方法
Outlook VBA教程:Apply方法 Outlook VBA教程:Assign方法
Outlook VBA教程:CancelResponseState方法 Outlook VBA教程:ClearConversationIndex方法
Outlook VBA教程:ClearRecurrencePattern方法 Outlook VBA教程:Close方法
Outlook VBA教程:Copy方法 Outlook VBA教程:CopyFile方法
Outlook VBA教程:CopyTo方法 Outlook VBA教程:CreateItem方法
Outlook VBA教程:CreateItemFromTemplate方法 Outlook VBA教程:CreateObject方法
Outlook VBA教程:CreateRecipient方法 Outlook VBA教程:Delete方法
版权所有 © 中山市飞娥软件工作室 证书:粤ICP备09170368号