PowerPoint VBA教程:Add方法

应用于 AddIns对象的 Add方法。

返回一个AddIn对象,该对象代表一个添加到加载宏列表中的加载宏文件。

expression.Add(Filename)

expression  必选。该表达式返回一个AddIns对象。

Filename  必选。String 类型。包含要添加到加载宏列表的加载宏的文件的完整名称(包括路径名和文件扩展名)。

说明

该方法并不加载新的加载宏。必须通过设置Loaded属性以加载该加载宏。

应用于 AnimationBehaviors对象的 Add方法。

返回一个AnimationBehavior对象,该对象代表一个新的动画动作。

expression.Add(Type, Index)

expression  必选。该表达式返回一个AnimationBehaviors对象。

Type  必选。MsoAnimType 类型。动画的动作。

MsoAnimType 可以是下列 MsoAnimType 常数之一。
msoAnimTypeColor
msoAnimTypeMixed
msoAnimTypeMotion
msoAnimTypeNone
msoAnimTypeProperty
msoAnimTypeRotation
msoAnimTypeScale

Index  可选。Long 类型。关于其他动画动作的动画的放置。默认值为 -1,表示如果省略 Index参数,新的动画动作将被添加到现有动画动作的末尾。

应用于 AnimationPoints 和 Sequences对象的 Add方法。

返回一个AnimationPointSequence对象,该对象代表一个新的动画点或序列。

expression.Add(Index)

expression  必选。该表达式返回上述对象之一。

Index  可选。Long 类型。动画点或动画序列相对于其他动画点或序列的位置。默认值为 -1,表示如果省略 Index参数,新的动画点或序列将被添加到现有动画点或序列的末尾。

应用于 ColorSchemes对象的 Add方法。

将一种配色方案添加到可用配色方案集合中。返回一个ColorScheme对象,该对象代表所添加的配色方案。

expression.Add(Scheme)

expression  必选。该表达式返回一个ColorSchemes对象。

Scheme  可选。ColorScheme对象。要添加的配色方案。可以是一张幻灯片或母版中的 ColorScheme对象,或者是任何打开的演示文稿的 ColorSchemes集合中的一个对象。如果省略此参数,则采用指定演示文稿 ColorSchemes集合中的第一个 ColorScheme对象(即第一个标准配色方案)。

说明

新配色方案基于指定幻灯片或母版使用的颜色,或者一个打开的演示文稿中指定配色方案中的颜色。

ColorSchemes集合最多可以包含 16 种配色方案。如果需要向集合中添加另一配色方案但 ColorSchemes集合已满,可以使用 Delete方法删除某个现有的配色方案。

请注意,Microsoft PowerPoint 在用户界面上添加配色方案之前会自动检测重复的配色方案;但是在 Visual Basic 的过程中添加配色方案时,不会进行这样的检测。过程必须进行自检以避免添加多余的配色方案。

应用于 Columns对象的 Add方法。

向现有表格中添加一个新列。返回一个Column对象,该对象代表表格中的新列。

expression.Add(BeforeColumn)

expression  必选。返回Columns对象的表达式。

BeforeColumn  可选。Long 类型。此索引号用于指定将在其前面插入新列的表格列。此参数必须为 Long 类型,最小值是 1,最大不能超过表格中的总列数。其默认值为 -1,表示如果忽略 BeforeColumn参数,插入的新列将作为表格中的最后一列。

应用于 Comments对象的 Add方法。

返回一个Comment对象,该对象代表一个添加到幻灯片中的新批注。

expression.Add(Left, Top, Author, AuthorInitials, Text)

expression  必选。该表达式返回一个Comments对象。

Left  必选。Single 类型。批注左边缘相对于演示文稿左边缘的位置(以磅为单位)。

Top  必选。Single 类型。批注上边缘相对于演示文稿上边缘的位置(以磅为单位)。

Author  必选。String 类型。批注的作者。

AuthorInitials  必选。String 类型。作者姓名的第一个大写字母。

Text  必选。String 类型。批注文本。

应用于 Designs对象的 Add方法。

返回一个Design对象,该对象代表一个新幻灯片设计。

expression.Add(designName, Index)

expression  必选。该表达式返回一个Designs对象。

designName  必选。String 类型。设计的名称。

Index  可选。Integer 类型。设计的索引号。其默认值为 -1,表示如果省略 Index参数,新的幻灯片设计将被添加到现有幻灯片设计的末尾。

应用于 ExtraColors对象的 Add方法。

如果尚未添加某颜色,则将该种颜色添加到其他颜色中,使之在演示文稿中可用。

expression.Add(Type)

expression  必选。该表达式返回一个ExtraColors对象。

Type  必选。MsoRGBType 类型。已添加的颜色的RGB 值。

应用于 NamedSlideShows对象的 Add方法。

创建一个新的命名幻灯片放映,并将其添加到指定演示文稿的命名幻灯片放映集合中。返回代表新命名幻灯片放映的NamedSlideShow对象。

expression.Add(Name, SafeArrayOfSlideIDs)

expression  必选。该表达式返回一个NamedSlideShows对象。

Name  必选。String 类型。幻灯片放映的名称。

SafeArrayOfSlideIDs  必选。Variant 类型。包含在幻灯片放映中出现的每张幻灯片的唯一幻灯片标识符。

说明

添加幻灯片放映时指定的名称就是用Run方法运行该放映时指定的参数。

应用于 Presentations对象的 Add方法。

创建一个演示文稿。返回一个代表新演示文稿的Presentation对象。

expression.Add(WithWindow)

expression  必选。该表达式返回一个Presentations集合。

WithWindow  可选。MsoTriState 类型。使用 MsoTrue 在可视窗口中创建演示文稿。

MsoTriState 可以是下列 MsoTriState 常数之一。
msoCTrue
msoFalse 新演示文稿不显示。
msoTriStateMixed
msoTriStateToggle
msoTrue 默认值。在可视窗口中创建演示文稿。

应用于 PrintRanges对象的 Add方法。

返回一个PrintRange对象,该对象代表要打印的连续幻灯片组。

expression.Add(Start, End)

expression  必选。该表达式返回一个PrintRanges对象。

Start  必选。Long 类型。要打印的幻灯片范围内的第一张幻灯片。必须小于或等于 End参数的值。

End  必选。Long 类型。要打印的幻灯片范围中的最后一张幻灯片。必须大于或等于 Start参数的值。

说明

必须将PrintOptions对象的RangeType属性设置为 ppPrintSlideRange 才能将该方法应用于 PrintRanges集合中的范围。

如果不想打印整个演示文稿,而要指定打印幻灯片的范围,则必须为每个要打印的连续幻灯片组添加一个打印范围。例如,如果要打印第一张、第三张到第五张、第八张和第九张幻灯片,必须添加三个打印范围对象。详细信息,请参阅有关此方法的示例。

使用ClearAll方法清除以前定义的打印范围。

应用于 Rows对象的 Add方法。

返回一个Row对象,该对象代表一个添加到现有表格中的新行。

expression.Add(BeforeRow)

expression  必选。该表达式返回一个Rows对象。

BeforeRow  可选。Long 类型。此索引号用于指定将在其前面插入新行的表格行)。此参数必须为整数,最小值是 1,最大不能超过表格中的总行数。其默认值为 -1,表示如果忽略 BeforeRow参数,插入的新行将作为表格中的最后一行。

应用于 Slides对象的 Add方法。

创建一张新的幻灯片,并添加到指定演示文稿中的幻灯片集合。返回一个代表新幻灯片的Slide对象。

expression.Add(Index, Layout)

expression  必选。该表达式返回一个Slides集合。

Index  必选。Long 类型。新幻灯片在 Slides集合中的索引号。此值不能超过现有幻灯片数 + 1。如果设为 1,新幻灯片将成为演示文稿的第一张幻灯片。

Layout  必选。PpSlideLayout 类型。要创建的幻灯片类型。

PpSlideLayout 可以是下列 PpSlideLayout 类型常数之一。
ppLayoutBlank
ppLayoutChart
ppLayoutChartAndText
ppLayoutClipartAndText
ppLayoutClipArtAndVerticalText
ppLayoutFourObjects
ppLayoutLargeObject
ppLayoutMediaClipAndText
ppLayoutMixed
ppLayoutObject
ppLayoutObjectAndText
ppLayoutObjectOverText
ppLayoutOrgchart
ppLayoutTable
ppLayoutText
ppLayoutTextAndChart
ppLayoutTextAndClipart
ppLayoutTextAndMediaClip
ppLayoutTextAndObject
ppLayoutTextAndTwoObjects
ppLayoutTextOverObject
ppLayoutTitle
ppLayoutTitleOnly
ppLayoutTwoColumnText
ppLayoutTwoObjectsAndText
ppLayoutTwoObjectsOverText
ppLayoutVerticalText
ppLayoutVerticalTitleAndText
ppLayoutVerticalTitleAndTextOverChart

说明

若要改变现有幻灯片的版式,请使用Layout属性。

应用于 TabStops对象的 Add方法。

为指定文本的标尺添加一个制表位。返回一个代表该制表位的TabStop对象。

expression.Add(Type, Position)

expression  必选。该表达式返回一个TabStops集合。

Type  必选。PpTabStopType 类型。指定文本与新制表位的对齐方式。

PpTabStopType 可以是下列 PpTabStopType 类型常数之一。
ppTabStopCenter
ppTabStopDecimal
ppTabStopLeft
ppTabStopMixed
ppTabStopRight

Position  必选。Single 类型。以磅为单位的新制表位的位置。

应用于 Tags对象的 Add方法。

为指定对象创建一个标记。如果标记已经存在,使用该方法将替换现有的标记值。

expression.Add(Name, Value)

expression  必选。该表达式返回一个Tags对象。

Name  必选。String 类型。新标记名称。使用“name”作为该参数的字符串以设置名称标记的值。

Value  必选。String 类型。新标记值。

说明

Tags对象包含每个标记的一对字符串:标记的名称和标记值。使用 Add方法创建一个标记,并使用NameValue方法返回标记的名称和值组件。

VBA示例

应用于 AddIns对象。

本示例将 MyTools.ppa 添加到加载宏列表中。


Set myAddIn = Application.AddIns.Add(FileName:="c:\my documents\mytools.ppa")
MsgBox myAddIn.Name & " has been added to the list"

应用于 ColorSchemes对象。 

本示例将新的配色方案添加到当前演示文稿的标准配色方案集合中。这个新配色方案是以当前演示文稿的第二张幻灯片中使用的颜色为基础的。


With ActivePresentation
    Set newClrScheme = .Slides(2).ColorScheme
    .ColorSchemes.Add Scheme:=newClrScheme
End With

应用于 Columns对象。 

本示例在表格(在第二张幻灯片上的第五个形状中)的第一列前创建一个新列。然后将新列的宽度设置为 72 磅(1 英寸)。


With ActivePresentation.Slides(2).Shapes(5).Table
    .Columns.Add(1).Width = 72
End With

应用于 NamedSlideShows对象。 

本示例为当前演示文稿添加一个命名幻灯片放映 Quick Show(该放映包含第二、第七和第九个幻灯片),然后运行该幻灯片放映。


Dim qSlides(1 To 3) As Long
With ActivePresentation
    With .Slides
        qSlides(1) = .Item(2).SlideID
        qSlides(2) = .Item(7).SlideID
        qSlides(3) = .Item(9).SlideID
    End With
    With .SlideShowSettings
        .NamedSlideShows.Add Name:="Quick Show", SafeArrayOfSlideIDs:=qSlides
        .RangeType = ppShowNamedSlideShow
        .SlideShowName = "Quick Show"
        .Run
    End With
End With

应用于 Presentations对象。

本示例创建一个演示文稿,并在其中添加一张幻灯片,然后保存该演示文稿。


With Presentations.Add
    .Slides.Add Index:=1, Layout:=ppLayoutTitle
    .SaveAs "Sample"
End With

应用于 PrintRanges对象。

本示例清除所有以前定义的打印范围,然后打印当前演示文稿的第一张、第三张到第五张、第八张和第九张幻灯片。


With ActivePresentation.PrintOptions
    .RangeType = ppPrintSlideRange
    With .Ranges
        .ClearAll
        .Add Start:=1, End:=1
        .Add Start:=3, End:=5
        .Add Start:=8, End:=9
    End With
End With
ActivePresentation.PrintOut

应用于 Rows对象。

本示例在现有表格的末尾创建一个新行,并将该新行的高度设置为 54 磅(0.75 英寸)。


With ActivePresentation.Slides(2).Shapes(5).Table
    .Rows.Add.Height = 54
End With

应用于 Slides对象。

本示例在当前演示文稿的开始处添加一张包含标题占位符的幻灯片。


ActivePresentation.Slides.Add Index:=1, Layout:=ppLayoutTitleOnly

本示例在当前演示文稿的末尾添加一张空白幻灯片。


With ActivePresentation.Slides
    .Add Index:=.Count + 1, Layout:=ppLayoutBlank
End With

应用于 TabStops对象。

本示例为当前演示文稿第一张幻灯片第二个形状的文本设置位于两英寸(144 磅)处的左对齐制表位。


Application.ActivePresentation.Slides(1).Shapes(2).TextFrame _
    .Ruler.TabStops.Add Type:=ppTabStopLeft, Position:=144

应用于 Tags对象。

本示例在当前演示文稿第一张幻灯片中添加名为 Priority 的标记,并设置名称标记的值。


With Application.ActivePresentation.Slides(1).Tags
    'Sets value for name tag
    .Add Name:="Name", Value:="New Figures"
    'Adds "Priority" tag with value "Low"
    .Add Name:="Priority", Value:="Low"
End With

应用于 ExtraColors对象。 

本示例将一种其他颜色添加到当前演示文稿中(如果此颜色尚未添加)。


ActivePresentation.ExtraColors.Add RGB(Red:=69, Green:=32, Blue:=155)

上页:PowerPoint VBA教程:Activate方法 下页:PowerPoint VBA教程:AddBaseline方法

PowerPoint VBA教程:Add方法

PowerPoint VBA教程:AddBaseline方法 PowerPoint VBA教程:AddCallout方法
PowerPoint VBA教程:AddComment方法 PowerPoint VBA教程:AddConnector方法
PowerPoint VBA教程:AddCurve方法 PowerPoint VBA教程:AddDiagram方法
PowerPoint VBA教程:AddEffect方法 PowerPoint VBA教程:AddLabel方法
PowerPoint VBA教程:AddLine方法 PowerPoint VBA教程:AddMediaObject方法
PowerPoint VBA教程:AddNode方法 PowerPoint VBA教程:AddNodes方法
PowerPoint VBA教程:AddOLEObject方法 PowerPoint VBA教程:AddPeriods方法
PowerPoint VBA教程:AddPicture方法 PowerPoint VBA教程:AddPlaceholder方法
PowerPoint VBA教程:AddPolyline方法 PowerPoint VBA教程:AddShape方法
PowerPoint VBA教程:AddTable方法 PowerPoint VBA教程:AddTextbox方法
版权所有 © 中山市飞娥软件工作室 证书:粤ICP备09170368号