PowerPoint VBA教程:To属性

应用于 ColorEffect对象的 To属性。

设置或返回 ColorFormat对象,该对象代表动画动作的 RGB 颜色值。可读写。

expression.To

expression  必选。该表达式返回一个ColorEffect对象。

说明

将此属性与 From属性联合使用以便从一种颜色切换到另一种颜色。

应用于 RotationEffect对象的 To属性。

设置或返回 Single 类型值,该值代表相对于屏幕所指定的对象的结束旋转角度(例如,90 度表示是完全水平的)。可读写。

expression.To

expression  必选。该表达式返回一个RotationEffect对象。

说明

将此属性与 From属性联合使用以便从一个旋转角度切换到另一个旋转角度。

默认值为 Empty,此情况下使用对象的当前位置。

应用于 PropertyEffect对象的 To属性。

设置或返回 Variant 类型值,该值代表对象属性的结束值。可读写。

expression.To

expression  必选。该表达式返回一个PropertyEffect对象。

说明

默认值为 Empty,此情况下使用对象的当前位置。

说明

请勿将此属性与ScaleEffectMotionEffect对象的ToXToY属性相混淆,后者仅用于缩放或移动效果。

VBA示例

应用于 ColorEffect对象。

以下示例添加一个颜色效果并且将该效果的颜色由带蓝色的浅绿更改为黄色。


Sub AddAndChangeColorEffect()
    Dim effBlinds As Effect
    Dim tmlTiming As TimeLine
    Dim shpRectangle As Shape
    Dim animColor As AnimationBehavior
    Dim clrEffect As ColorEffect
    Set shpRectangle = ActivePresentation.Slides(1).Shapes _
        .AddShape(Type:=msoShapeRectangle, Left:=100, _
        Top:=100, Width:=50, Height:=50)
    Set tmlTiming = ActivePresentation.Slides(1).TimeLine
    Set effBlinds = tmlTiming.MainSequence.AddEffect(Shape:=shpRectangle, _
        effectId:=msoAnimEffectBlinds)
    Set animColor = tmlTiming.MainSequence(1).Behaviors _
        .Add(Type:=msoAnimTypeColor)
    Set clrEffect = animColor.ColorEffect
    clrEffect.From.RGB = RGB(Red:=255, Green:=255, Blue:=0)
    clrEffect.To.RGB = RGB(Red:=0, Green:=255, Blue:=255)
End Sub

应用于 RotationEffect对象。

以下示例添加一个旋转效果,并且立即将旋转角度从 90 度更改为 270 度。


Sub AddAndChangeRotationEffect()
    Dim effBlinds As Effect
    Dim tmlTiming As TimeLine
    Dim shpRectangle As Shape
    Dim animColor As AnimationBehavior
    Dim rtnEffect As RotationEffect
    Set shpRectangle = ActivePresentation.Slides(1).Shapes(1)
    Set tmlTiming = ActivePresentation.Slides(1).TimeLine
    Set effBlinds = tmlTiming.MainSequence.AddEffect(Shape:=shpRectangle, _
        effectId:=msoAnimEffectBlinds)
    Set animColor = tmlTiming.MainSequence(1).Behaviors.Add(Type:=msoAnimTypeRotation)
    Set rtnEffect = animColor.RotationEffect
    rtnEffect.From = 90
    rtnEffect.To = 270
End Sub

上页:PowerPoint VBA教程:TitleMaster属性 下页:PowerPoint VBA教程:Top属性

PowerPoint VBA教程:To属性

PowerPoint VBA教程:Top属性 PowerPoint VBA教程:ToX属性
PowerPoint VBA教程:ToY属性 PowerPoint VBA教程:Tracking属性
PowerPoint VBA教程:Transparency属性 PowerPoint VBA教程:TransparencyColor属性
PowerPoint VBA教程:TransparentBackground属性 PowerPoint VBA教程:TriggerDelayTime属性
PowerPoint VBA教程:TriggerShape属性 PowerPoint VBA教程:TriggerType属性
PowerPoint VBA教程:Type属性 PowerPoint VBA教程:Underline属性
PowerPoint VBA教程:UpdateLinksOnSave属性 PowerPoint VBA教程:UseFormat属性
PowerPoint VBA教程:UseLongFileNames属性 PowerPoint VBA教程:UseTextColor属性
PowerPoint VBA教程:UseTextFont属性 PowerPoint VBA教程:Value属性
PowerPoint VBA教程:VBASigned属性 PowerPoint VBA教程:VBE属性
版权所有 © 中山市飞娥软件工作室 证书:粤ICP备09170368号